forked from Misaki/GhostEngine
Misaki
4173ff2432
Major overhaul of resource barrier and state tracking in RenderGraph: - Introduce ResourceBarrierData for explicit (layout, access, sync) tracking. - Separate aliasing and transition barriers; explicit aliasing support. - Remove BufferHint; infer buffer usage from BufferUsage flags. - Update TextureAccess/BufferAccess to include usage requirements. - Improve enums (BarrierSync, BarrierAccess, BarrierLayout) for D3D12 alignment. - Update D3D12CommandBuffer to use new barrier data and error handling. - Make D3D12DescriptorHeap a class; add ReleaseSampler to IResourceDatabase. - Reset resource pools and aliasing managers each frame. - Batch and flush barriers efficiently per pass. - Update HLSL mesh shader macros to [NumThreads]. - Remove obsolete code and improve documentation. This refactor improves correctness, extensibility, and prepares for advanced features.
97 lines
2.9 KiB
HLSL
97 lines
2.9 KiB
HLSL
#ifndef BUILTIN_COMMON_HLSL
|
||
#define BUILTIN_COMMON_HLSL
|
||
|
||
struct Vertex
|
||
{
|
||
float4 position;
|
||
float4 normal;
|
||
float4 tangent;
|
||
float4 uv;
|
||
float4 color;
|
||
};
|
||
|
||
// Resource descriptor heap definitions
|
||
|
||
#define GLOBAL_TEXTURE2D_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_TEXTURE3D_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_TEXTURECUBE_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_TEXTURE2D_ARRAY_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_TEXTURECUBE_ARRAY_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_BUFFER_HEAP ResourceDescriptorHeap
|
||
#define GLOBAL_SAMPLER_HEAP SamplerDescriptorHeap
|
||
|
||
// Bindless resource type definitions
|
||
|
||
#define TEXTURE2D uint
|
||
#define TEXTURE3D uint
|
||
#define TEXTURECUBE uint
|
||
#define TEXTURE2D_ARRAY uint
|
||
#define TEXTURECUBE_ARRAY uint
|
||
|
||
#define SAMPLER uint
|
||
|
||
#define STRUCT_BUFFER uint
|
||
#define BYTE_ADDRESS_BUFFER uint
|
||
|
||
|
||
// Texture and sampler access macros
|
||
|
||
#define GET_TEXTURE2D(id) GLOBAL_TEXTURE2D_HEAP[id]
|
||
#define GET_TEXTURE2D_ARRAY(id) GLOBAL_TEXTURE2D_ARRAY_HEAP[id]
|
||
#define GET_TEXTURE3D(id) GLOBAL_TEXTURE3D_HEAP[id]
|
||
#define GET_TEXTURECUBE(id) GLOBAL_TEXTURECUBE_HEAP[id]
|
||
#define GET_TEXTURECUBE_ARRAY(id) GLOBAL_TEXTURECUBE_ARRAY_HEAP[id]
|
||
#define GET_BUFFER(id) GLOBAL_BUFFER_HEAP[id]
|
||
#define GET_SAMPLER(id) GLOBAL_SAMPLER_HEAP[id]
|
||
|
||
#define SAMPLE_TEXTURE2D(texId, sampId, uv) SampleTexture2D(texId, sampId, uv)
|
||
#define SAMPLE_TEXTURE2D_LEVEL(texId, sampId, uv, level) SampleTexture2DLevel(texId, sampId, uv, level)
|
||
#define SAMPLE_TEXTURE2D_ARRAY(texId, sampId, uvw) SampleTextureArray(texId, sampId, uvw)
|
||
|
||
|
||
#define OUTPUT_TRIANGLE_TOPOLOGY OutputTopology("triangle")
|
||
#define OUTPUT_LINE_TOPOLOGY OutputTopology("line")
|
||
|
||
|
||
static inline float4 SampleTexture2D(uint texId, uint sampId, float2 uv)
|
||
{
|
||
Texture2D tex = GET_TEXTURE2D(texId);
|
||
SamplerState samp = GET_SAMPLER(sampId);
|
||
return tex.Sample(samp, uv);
|
||
}
|
||
|
||
static inline float4 SampleTexture2DLevel(uint texId, uint sampId, float2 uv, float level)
|
||
{
|
||
Texture2D tex = GET_TEXTURE2D(texId);
|
||
SamplerState samp = GET_SAMPLER(sampId);
|
||
return tex.SampleLevel(samp, uv, level);
|
||
}
|
||
|
||
static inline float4 SampleTextureArray(uint texId, uint sampId, float3 uvw)
|
||
{
|
||
Texture2DArray tex = GET_TEXTURE2D_ARRAY(texId);
|
||
SamplerState samp = GET_SAMPLER(sampId);
|
||
return tex.Sample(samp, uvw);
|
||
}
|
||
|
||
static inline Vertex LoadVertexData(uint vertexID, uint groupID, BYTE_ADDRESS_BUFFER vertexBuffer, BYTE_ADDRESS_BUFFER indexBuffer)
|
||
{
|
||
ByteAddressBuffer vertices = GET_BUFFER(vertexBuffer);
|
||
ByteAddressBuffer indices = GET_BUFFER(indexBuffer);
|
||
|
||
// Compute the triangle’s vertex indices
|
||
uint indexOffset = (groupID * 3 + vertexID) * 4; // uint32 index
|
||
uint vertexIndex = indices.Load(indexOffset);
|
||
|
||
return vertices.Load<Vertex>(vertexIndex * sizeof(Vertex));
|
||
}
|
||
|
||
template<typename T>
|
||
static inline T LoadData(BYTE_ADDRESS_BUFFER buffer, uint index)
|
||
{
|
||
ByteAddressBuffer buf = GET_BUFFER(buffer);
|
||
return buf.Load<T>(index * sizeof(T));
|
||
}
|
||
|
||
#endif // BUILTIN_COMMON_HLSL
|